Проблема с временной таблице в lookup

[Vasiliusis]

Добрый день!
Есть код, который должен при некотором условии выполнять вставку данных в таблицу, которая хранится на сервере, НО которую в коде я делаю временной. После этого, эти данные должны выпадать в lookup'е

public void lookup()
{
    TableObj              tempTable1, table1;
    SysTableLookup              sysTableLookup;


    ;
    //Делаем таблицу временной
    tempTable1.setTmp();

    sysTableLookup = SysTableLookup::newParameters(tablenum(TableObj), this);

    //Добавляем столбцы
    sysTableLookup.addLookupfield(fieldnum(TableObj, CustAccount));
    sysTableLookup.addLookupfield(fieldnum(TableObj, Name));
    sysTableLookup.addLookupfield(fieldnum(TableObj, Desc));



    ttsbegin;
    //перебираем
    while select * from table1
        order by CustAccount desc
        {
                if (table1.CustAccount == 'Target')
                {
                    
                    tempTable1.data(table1);
                    tempTable1.insert();
                    
                }

        }
     ttscommit;

    //BP Deviation Documented
    sysTableLookup.parmTmpBuffer(tempTable1);
    sysTableLookup.performFormLookup();

}

На условие выборки не смотрите, оно схематично (это чтобы вы мне через Query не советовали делать, в реальности выборка сложнее)

Так вот: проблема в том, что когда данные для выборки и вставки есть - они выводятся спокойно.
Но вот когда их нет - выводится полный набор столбцов из таблицы в БД. А должно быть по идее то пусто! В чем причина? как это исправить?

MS DAX 2009

[Player1]

this.text(''); в самом началу лукапа не спасет?

А где у вас передача временной в sysTableLookup? Я бы так делал:

this.text('');
tempTable1.setTmp();
... //заполнение временной
sysTableLookup = SysTableLookup::construct();
sysTableLookup.parmCallingControl(this);
sysTableLookup.parmTmpBuffer(tempTable1);
sysTableLookup.parmTableId(tableNum(TableObj));
sysTableLookup.addLookupfield(fieldNum(TableObj, CustAccount), true);
sysTableLookup.performFormLookup();

[Vasiliusis]

Цитата:

Сообщение от Player1

this.text(''); в самом началу лукапа не спасет?

А где у вас передача временной в sysTableLookup?

Нет не спасло. Код не сработал.

Передача ниже:

    //BP Deviation Documented
    sysTableLookup.parmTmpBuffer(tempTable1);
    sysTableLookup.performFormLookup();

[S.Kuskov]

Походу косяк в реализации SysTableLookup
Проверка на временность таблицы там выглядит следующим образом

public FormRun formRun()
{
...
if (tmpBuffer)
    {
        formDataSource.init();
        //BP deviation documented
        formDataSource.cursor().setTmp();       // if using non-temp table in tmp mode
        formDataSource.cursor().setTmpData(tmpBuffer);
    }
...
}

Естественно когда данных в курсоре нет, это равносильно тому что он NULL.

Должно заработать, если подкорректировать условие на что-то типа

if (tmpBuffer.TableId != TableNum(Common))