Клонировать QueryRun

[Vasiliusis]

Добрый день!
Вопрос на 5 копеек: у меня есть объект queryRun1. Как мне создать его копию и поместить скажем в queryRun2?

[S.Kuskov]

queryRun2 = new QueryRun(queryRun1.query());

Так?

[Vasiliusis]

Цитата:

Сообщение от S.Kuskov

queryRun2 = new QueryRun(queryRun1.query());

Так?

не пойдет, на датасорсы queryRun1 перед копированием вешаются рэйнджи. В queryRun1.query() этих рэйнджей нету... в query по-моему вообще нельзя рэйнджи вешать, хотя я может ошибаюсь

[Vasiliusis]

Я соврал, в query их как раз и нужно вешать))) тем не менее, выборка в queryRun1 и queryRun2 не совпадают...

[Vasiliusis]

В общем, вот почему не сходится: queryRun1 - это запрос датасорса на форме. Датасорс выводится в грид. На грид вешается фильтр... вот это самое значение фильтра при копировании не учитывается. учитываются только рэйнджи, которые прописаны программно (там executeQuery перекрыт...). Вот. как добавить значения фильтра из грида в queryRun2?

[S.Kuskov]

Цитата:

Сообщение от Vasiliusis

хотя я может ошибаюсь

Ошибаетесь. Структура запроса: джойны, рейнджы, сортировки и т.д. - это все задается на уровне query.

QueryRun же это класс отвечающий за перебор записей соответствующего Query.

К стати, на уровне QueryRun ещё задается сопоставление курсоров запроса с конкретными экземплярами временных таблиц, если таковые участвуют в запросе. Вот они видимо не скопируются.

Можно ещё попробовать вот так, но не уверен что это поможет.

queryRun2 = new QueryRun(queryRun1.pack());

[S.Kuskov]

Цитата:

Сообщение от Vasiliusis

В общем, вот почему не сходится: queryRun1 - это запрос датасорса на форме. Датасорс выводится в грид. На грид вешается фильтр... вот это самое значение фильтра при копировании не учитывается. учитываются только рэйнджи, которые прописаны программно (там executeQuery перекрыт...). Вот. как добавить значения фильтра из грида в queryRun2?

Вам в этом случае нужен не DataSource.QueryRun().Query(), а DataSource.Query().

Извиняюсь, наоборот. Как передать в отчет отфильтрованные данные из формы?

[TasmanianDevil]

Цитата:

Сообщение от S.Kuskov

но не уверен что это поможет

Поможет, класс SysQuery именно так реализует всякие сервисные подсчеты для передаваемых запросов ...

[dech]

Цитата:

Сообщение от Vasiliusis

Я соврал, в query их как раз и нужно вешать))) тем не менее, выборка в queryRun1 и queryRun2 не совпадают...

Значит вы делаете что-то не так...

static void QueryRunTest(Args _args)
{
    Query                   q;
    QueryRun                qr1, qr2;
    QueryBuildDataSource    qbds;
    InventTable             inventTable;
    ;
    
    q = new Query();
    qbds = q.addDataSource(tablenum(InventTable));
    qbds.addRange(fieldnum(InventTable, ItemId)).value("2320");
    qbds.addSelectionField(fieldnum(InventTable, ItemId));
    qbds.addSelectionField(fieldnum(InventTable, ItemName));
 
    qr1 = new QueryRun(q);
    while (qr1.next())
    {
        inventTable = qr1.get(tablenum(InventTable));
        info(strfmt("%1 (%2)", inventTable.ItemId, inventTable.ItemName));
    }
    
    info("");
    
    qr2 = new QueryRun(qr1.query());
    while (qr2.next())
    {
        inventTable = qr2.get(tablenum(InventTable));
        info(strfmt("%1 (%2)", inventTable.ItemId, inventTable.ItemName));
    }
}

[Vasiliusis]

Цитата:

Сообщение от S.Kuskov

Вам в этом случае нужен не DataSource.QueryRun().Query(), а DataSource.Query().

Извиняюсь, наоборот. Как передать в отчет отфильтрованные данные из формы?

DataSource.QueryRun().Query() помогло. благодарю!

[S.Kuskov]

Цитата:

Сообщение от TasmanianDevil

Поможет, класс SysQuery именно так реализует всякие сервисные подсчеты для передаваемых запросов ...

полезный класс, если нужно, например, пересобрать запрос, объеденить. Но заметьте, работает он все равно с классом Query, а не QueryRun. Поэтому вести речь о клонировании именно QueryRun, со всем его контекстом - вообще говоря нельзя.

[TasmanianDevil]

S.Kuskov, неправда Ваша - всякие count<Всякое>() в нем работают именно с объектом типа QueryRun и именно его клонируют через контейнер, производя вычисления.

[S.Kuskov]

Цитата:

Сообщение от TasmanianDevil

S.Kuskov, неправда Ваша - всякие count<Всякое>() в нем работают именно с объектом типа QueryRun и именно его клонируют через контейнер, производя вычисления.

Действительно так. Но только это не помогает избежать того о чем я писал. Связь со временной таблицей теряется все равно:

Вот небольшой пример:

static void JobTEST_QueryRunPack(Args _args)
{
    Query query;
    QueryRun queryRun1, queryRun2;
    TmpABC TmpABC1;
    ;
    
    query = new Query();
    query.addDataSource(tableNum(TmpABC));
    
    TmpABC1.clear();
    TmpABC1.Amount = 123.45;
    TmpABC1.doInsert();
    
    queryRun1 = new QueryRun(query);
    queryRun1.setCursor(TmpABC1);
    info(strfmt("SysQuery::countTotal(queryRun1): %1", SysQuery::countTotal(queryRun1))); // 0
    info("");

    queryRun2 = new QueryRun(queryRun1.pack()); // "клонируем" QueryRun

    info("queryRun2:");
    info("{");
    while (queryRun2.next()) // {}
    {
        TmpABC1 = queryRun2.get(tableNum(TmpABC));
        
        info(strfmt("%1", TmpABC1.Amount));
    }
    info("}");
    info("");

    info("queryRun1:");
    info("{");
    while (queryRun1.next()) // {123,45}
    {
        TmpABC1 = queryRun1.get(tableNum(TmpABC));

        info(strfmt("%1", TmpABC1.Amount));
    }
    info("}");
}

[TasmanianDevil]

Цитата:

Сообщение от S.Kuskov

Связь со временной таблицей теряется все равно:

Угу, про времянки, читая ответ по диагонали, я как-то пролетел мимо