Вопрос по правам.

[_scorp_]

Первый вопрос. Можно массово. В контейнере groups перечислите группы, для которых нужно закрыть доступ на menuItem. Предполагается что кнопка это menuItem. Вот Job:

static void setRights(Args _args)
{
    SecurityKeySet      secSet;
    UserGroupInfo       userGroup;
    DomainInfo          domain;
    AccessType          currentAccessType;
    MenuItemName        name = menuItemDisplayStr(InventTable);
    AccessRecordType    type = AccessRecordType::MenuItemDisplay;
    container           groups = ['group1, group2', 'group3'];
    ;
    while select userGroup
        where userGroup.Id != 'Admin'
    {
        if (confind(groups, userGroup.Id) != 0)
        {
            while select domain
            {
                secSet = SysSecurity::constructSecurityKeySet();
                secSet.loadGroupRights(userGroup.id, domain.Id);
                currentAccessType = secSet.menuItemAccess(name, type);
                if (currentAccessType != AccessType::NoAccess)
                {
                    secSet.menuItemAccess(name, type, currentAccessType);
                    xAccessRightsList::saveSecurityRights(secSet.pack(), userGroup.Id, domain.Id);
                }
            }
        }
    }
}

Второй вопрос не понял.

[axalex]

Цитата:

Сообщение от _scorp_

Первый вопрос. Можно массово. В контейнере groups перечислите группы, для которых нужно закрыть доступ на menuItem. Предполагается что кнопка это menuItem.

Да, menuitem. Оказалось не так сложно. Спасибо - буду пробовать!

Цитата:

Второй вопрос не понял.

В списке пользователей у меня висит некий user с кодом пользователя Admin. Его невозможно отключить. Якобы, тот кто первый получает данный код пользователя, становится главным администратором в DAX.
При попытке удалить\отключить - вываливается ошибка "Невозможно произвести замену Admin". Вскрываем ошибку - вылетает код (для понятности):

//Класс UserInfoHelp
static server boolean validateAdmin(UserInfo _userInfo)
{
    #admin
    UserGroupList   _userGroupList;
    ;
    setprefix("@SYS29011");

    if (_userInfo.Id == #AdminUser)
    {
        error(strfmt("@SYS29012", _userInfo.Id));
        return false;
    }

    select firstonly RecId from _userGroupList
        where _userGroupList.UserId == _userInfo.Id &&
              _userGroupList.GroupId == #AdminUserGroup;

    if  (_userGroupList)
    {
        select firstonly RecId from _userGroupList
            where _userGroupList.UserId != _userInfo.Id &&
                  _userGroupList.GroupId == #AdminUserGroup;

        if (!_userGroupList)
        {
            error(strfmt("@SYS29013", _userInfo.Id));
            return false;
        }
    }
    return true;
}

Можно ли пользователя удалять\заменить? Обязательно ли, если удалю, присвоить код пользователя "Admin" другому пользователю?