как перевести строку в число, используя региональные настройки?

вопрос к знатокам C#: как перевести строку в число, используя региональные настройки?

[George Nordic]

В WinApi есть функция getLocaleInfo()

Для десятичного разделителя: WinAPI::getLocaleInfo(#LOCALE_USER_DEFAULT, #LOCALE_SDECIMAL);
Для разделителя тысяч: WinAPI::getLocaleInfo(#LOCALE_USER_DEFAULT, #LOCALE_STHOUSAND);

Можно рыть в эту сторону или погуглить пример с этой функцией.

С Уважением,
Георгий

[Владимир Максимов]

Если не ошибаюсь, то strFmt() переводит как раз на основе текущих региональных настроек. Или надо произвольные региональные настройки?

[George Nordic]

Да, в Аксапте. Вопрос, насколько я понял, что C#.

если бы бездумно не выдернули из правильной темы мой вопрос, было бы все ясно. Весь контекст темы я продублить не смогу.

Суть вопроса: str2int отрабатывает некорректно.

[gl00mie]

У меня работает вот такой пример:

System.Globalization.CultureInfo    myCulture;
System.Threading.Thread             myThread;
Integer                             i;
str                                 s = "-123 456 789,00р.";
;
myThread = System.Threading.Thread::get_CurrentThread();
myCulture = myThread.get_CurrentCulture();
try
{
    i = System.Int32::Parse( s, System.Globalization.NumberStyles::Any, myCulture );
    info( strfmt( '%1', i ) );
}
catch (Exception::CLRError)
{
    info( AifUtil::getClrErrorMessage() );
}

атас. А в одну функцию нету?

[konopello]

Цитата:

атас. А в одну функцию нету?

вот так вот, хоть бы за это респект человеку поставил!

[AndyD]

Можно еще воспользоваться классом Convert

    System.String                           string;
    System.Double                           double;
    System.Int32                            int32;
    System.Globalization.CultureInfo        cultureInfo = System.Globalization.CultureInfo::CreateSpecificCulture("en-us");
    ;
    string = "-123,456,789.52";
    try
    {
        double = System.Convert::ToDouble(string, cultureInfo.get_NumberFormat());
        int32 = System.Convert::ToInt32(double);
    }
    catch
    {
    }

Если строка соответствует текущему формату, то можно вызвать просто System.Convert::ToDouble(string)

спасибо всем участникам. А респектами я не пользуюсь

[Владимир Максимов]

Цитата:

Сообщение от otkudao

Суть вопроса: str2int отрабатывает некорректно.

Для корректной работы функций str2num() достаточно чтобы у символьного представления числа не было разделителей тысяч и разделителем целой и дробной части выступала точка.

Другими словами необходимо:

1. Удалить символы-разделители тысяч
2. Установить в качестве разделителя целой и дробной части точку

static void JOB_test(Args _args)
{
    str     strSeparators;
    str     strThousend;
    str     strPoint;
    str     strNumber = strFmt("%1",123456789.01);
    real    realNumber;

    ;

    print "Исходная строка      = ", strNumber;

    // Символы-разделители 
    strSeparators   = strRem(strFmt("%1",1111.11),"1");
    // Разделитель целой и дробной части
    strPoint        = subStr(strSeparators, strLen(strSeparators),1);
    // Разделитель тысяч
    strThousend     = strRem(strSeparators, strPoint);

    // Удаляем разделитель тысяч
    strNumber = strRem(strNumber, strThousend);
    // Заменяем разделитель целой и дробной части на точку
    //strNumber = global::strReplace(strNumber, strPoint, ".");
    strNumber = strPoke(strNumber,".",strFind(strNumber, strPoint, 1, strLen(strNumber)));

    // Собственно преобразование
    realNumber = str2num(strNumber);

    print "После преобразования = ", strNumber;
    print "Первод в число       = ", realNumber;
    pause;

}

[konopello]

Цитата:

спасибо всем участникам. А респектами я не пользуюсь

ааа, понимаю